1 REM ***ENHANCEDEYE VER 2.1 3/1/83***

1010 GOTO 2000

1020 REM ***KEYBOARDCOMMAND PROCESSOR***

1100 CALL SC

1105 GOSUB 3170

1110 IF NOT PEEK (775) GOTO 1100

1120 X$ = CHR$ ( PEEK (774) - 128)

1130 IF X$ = "<" OR X$ = "," THEN ND = 1: GOSUB 3000: GOTO 1100

1140 IF X$ = ">" OR X$ = "." THEN ND = 2: GOSUB 3000: GOTO 1100

1150 IF X$ = " " THEN GET X$:I = FRE (0): GOTO 1100

1160 IF X$ = "C" THEN HGR : GOTO 1100

1180 IF X$ = "E" THEN SC = BI: POKE 770,1: GOTO 1100

1181 IF X$ = "T" THEN POKE 49235,0: HTAB 1: VTAB 23: CALL 64668: PRINT "OLD SOAKTIME: ";SO;: INPUT " NEW: ";SO:S1 = INT (SO / 256): POKE 769,S1: POKE 768,SO - (S1 * 256): POKE 49234,0: GOTO 1100

1182 IF X$ = "F" THEN SC = BI: POKE 770,2: GOTO 1100

1183 IF X$ = "U" THEN SC = BI: POKE 770,0: GOTO 1100

1185 IF X$ = "N" THEN SC = GE: GOTO 1100

1187 IF X$ = "G" THEN SX = SO:SO = SO * 1.22:S1 = INT (SO / 256): POKE 769,S1: POKE 768,SO - (S1 * 256):X2 = PEEK (770): POKE 770,3: CALL SC: POKE 770,X2:SO = SX: GOSUB 3110: GET X$

1190 IF X$ = "S" THEN HTAB 1: VTAB 23: CALL 64578: INPUT "SAVE PICTURE AS? ";F$: VTAB 23: CALL 64578: IF F$ < > "" THEN PRINT D$;"BSAVE ";F$;",A$2000,L$2000"

1206 IF X$ = "L" THEN HTAB 1: VTAB 23: CALL 64578: INPUT "LOAD WHICH PICTURE? ";F$: VTAB 23: CALL 64578: IF F$ < > "" THEN PRINT D$;"BLOAD ";F$;",A$2000": GET X$

1225 IF X$ = "Q" THEN HOME : TEXT : END

1230 IF X$ < > "P" GOTO 1100

1260 PRINT USR ((256 * 37) + 128)

1265 REM *CHANGE37 TO 40 FOR FULL WIDTH PICTURE IN LINE 1260

1270 VTAB 21: CALL 64578

1320 GOTO 1100

2000 REM ***INITIALIZATION***

2010 PRINT CHR$ (4);"BLOAD ENHANCER,A$8100"

2015 PRINT CHR$ (4);"BLOAD EPRINT,A$8600"

2020 LET D$ = CHR$ (4)

2030 LET BE = 65338

2040 LET GE = 33024

2050 DF = 20

2060 BI = GE + 3

2075 WH = GE + 6

2080 SC = GE

2100 PRINT "MICRONEYE SLOT? ";: GET SL: IF SL < 1 OR SL > 7 THEN CALL BE: GOTO 2100

2110 POKE 772,SL * 16

2120 HGR

2130 POKE 773,0

2140 POKE 768,0: POKE 769,1:SO = 256

2160 POKE 10,76: POKE 11,0: POKE 12,134

2170 REM ***USRADR FOR EPSON CALL***

2200 HOME : GOSUB 3110

2210 ONERR GOTO 4000

2230 GOTO 1100

3000 REM ***EXPOSUREADJUST ROUTINE***

3010 IF ND < > D OR (RD AND U(D) > 2) THEN RD = 1:U(ND) = INT (U(D) / 2): GOTO 3030

3020 RD = 0:U(D) = U(D) * 2

3030 D = ND

3040 IF D = 2 AND (SO + U(2) > 8000) THEN U(2) = 8000 - SO: GOTO 3060

3050 IF D = 1 AND SO < U(1) THEN U(1) = SO

3060 IF D = 2 THEN SO = SO + U(2)

3070 IF D = 1 THEN SO = SO - U(1)

3080 IF U(D) < 1 THEN U(D) = 1

3090 IF SO < 1 THEN SO = 1

3100 IF SO > 8000 THEN SO = 8000

3110 S1 = INT (SO / 256): POKE 769,S1

3120 POKE 768,SO - (S1 * 256)

3170 VTAB 23: HTAB 1: PRINT "EXPOSURE ";SO;

3190 CALL 64578

3200 RETURN

4000 HTAB 1: VTAB 23: CALL 64578

4010 PRINT "NO SUCH FILE, PRESS <RETURN>...";

4020 GET X$:X = FRE (0)

4030 HOME

4040 GOTO 1100

9000 REM *************************

9010 REM *PEEK AND POKE DEFINITIONS

9020 REM *************************

9040 REM *768 -- SOAKTIME (LSB)

9050 REM *769 -- SOAKTIME (MSB)

9060 REM *770 -- ENHANCE MODE

9070 REM * 0 = NO ENHANCEMENT

9080 REM * 1 = ENHANCE W/O FILLIN

9090 REM * 2 = ENHANCE WITH FILLIN

9100 REM * 3 = OVERLAY THIS SCAN AND PREV FOR GREY EFFECT

9110 REM *772 -- MICRONEYE SLOT * 16

9120 REM *773 -- SCREEN SEGMENT SELECTOR (NORMAL MODE ONLY)

9130 REM * 0 = TOP THIRD OF SCREEN

9140 REM * 40 = MIDDLE THIRD

9150 REM * 80 = BOTTOM THIRD

9160 REM *774 -- 1 = KEY HIT DURING SCAN

9165 REM *775 -- VALUE OF KEY HIT

9170 REM *****************************