100 GOTO 160: REM ---COMMANDER---

110 REM ******THEFOLLOWING REMARKS LEAVE ROOM FOR TEXTPAGE 2 WHICH OVERLAPS WHERE APPLESOFT PROGRAMS RESIDE*******

120 REM *****************************************************************************************************************************************************************************************************************************************

130 REM ***********************************************************************************************************************************************************************

140 REM *****************************************************************************************************************************************************************************************************************************************

150 REM *****************************************************************************************************************************************************************************************************************************************

160 HOME

170 LET GE = 32768

180 LET P2 = GE + 3

190 LET D$ = CHR$ (4)

200 PRINT D$;"BLOAD CAMASM,A$8000"

210 DIM Y$(1)

220 Y$(0) = "NO":Y$(1) = ""

230 INPUT "MICRONEYE INTERFACE SLOT# ";SL

240 POKE 771,SL * 16

250 HOME : HGR

260 VTAB 22: HTAB 1: INPUT "DECIMAL COMMAND? ";CM

270 POKE 768,CM

280 IF CM < 192 THEN CALL 65338: GOTO 260

290 C = CM - 192

300 AL = C < 32: IF NOT AL THEN C = C - 32

310 WI = C < 16: IF NOT WI THEN C = C - 16

320 B7 = C < 8: IF NOT B7 THEN C = C - 8

330 A1 = C < 4: IF NOT A1 THEN C = C - 4

340 SO = C > = 2: IF SO THEN C = C - 2

350 SE = C < 1

360 PRINT Y$(AL);"ALT,";Y$(WI);"WIDEPIX,";Y$(B7);"7BIT,";Y$(A1);"1ARRAY,";Y$(SO);"SOAK,";Y$(SE);"SEND"

370 RC = 512: IF A1 THEN RC = 256

380 CB = 32: IF B7 THEN CB = 37

390 IF WI THEN CB = CB * 2

400 IF AL THEN CB = INT (CB / 2):RC = RC / 2: IF CB = 18 THEN CB = 19

410 POKE 778,0: IF RC > 255 THEN POKE 778,RC / 256

420 IF RC > 255 THEN RC = RC - 256: GOTO 420

430 IF CB = 74 THEN CB = 73

440 IF NOT SE THEN GOTO 580

450 POKE 777,RC

460 POKE 768,CM

470 POKE 776,CB

475 POKE 779,0

480 INPUT "SOAKTIME(MSECS): ";ST

490 I = INT (ST / 256)

500 POKE 770,I

510 POKE 769,ST - (I * 256)

520 PRINT "(PRESS ANY KEY TO RETURN, 'Q' TO QUIT)";

530 CALL P2

540 CALL GE

550 X$ = CHR$ ( PEEK (773) - 128)

560 IF X$ < > "Q" THEN GOTO 250

570 HOME : END

580 POKE 49295 + SL,CM

590 IF PEEK (49152) < 128 GOTO 580

600 POKE 49168,0

610 X$ = CHR$ ( PEEK (49152))

620 GOTO 560

800 REM *************************

810 REM *PEEK AND POKE DEFINITIONS

820 REM *************************

830 REM * 768 -- CAMERA COMMAND

840 REM * 769 -- SOAKTIME (LSB)

850 REM * 770 -- SOAKTIME (MSB)

860 REM * 771 -- MICRONEYE SLOT * 16

870 REM * 772 -- 1 = KEY HIT DURING SCAN

880 REM * 773 -- ASCII VALUE OF KEY HIT

890 REM * 774 -- WHITECT (LSB)

900 REM * 775 -- WHITECT (MSB)

910 REM * 776 -- ROWSIZE IN BYTES

920 REM * 777 -- ROWS IN IMAGE *2 (LSB)

930 REM * 778 -- ROWS IN IMAGE * 2 (MSB

940 REM * 779 -- 1 = RETURN TO BASIC AFTER EACH SCAN

950 REM * 0 = SEND CAMERA IMAGES UNTIL KEY PRESSED

960 REM * 780 -- BYTES/ROW TO DISPLAY ON SCREEN

970 REM *****************************